specification CO4System [user,up1,down1,up2,down2,up3,down3,signal,OK] : noexit

  library CO4_DATATYPES endlib
  library Boolean, NaturalNumber endlib

behaviour

(
  ( UserInput [user] [> exit )
  |[user]|
  KBHierarchy [user,up1,down1,up2,down2,up3,down3,signal]
)
>> Ring [OK]

where


  process KBHierarchy [user,up1,down1,up2,down2,up3,down3,signal] : exit :=
    (
      (
        (
  	(
  	  InitIndividualKB [user,down1,up1,signal] (base1)
  	  |||
  	  InitIndividualKB [user,down1,up1,signal] (base2)
  	)
  	|[user,down1,up1]|
  	SerializeIndividualKB [user,down1,up1]
        )
        |[up1,down1]|
        ( hide up in InitQueue [up1,up] |[up]|
          InitGroupKB [up,down1,down2,up2,signal] (base3) )
      )
      |||
      InitIndividualKB [user,down2,up2,signal] (base4)
    )
    |[up2,down2]|
    ( hide up in InitQueue [up2,up] |[up]|
      InitGroupKB [up,down2,down3,up3,signal] (base5) )
    |[down3,up3]|
    exit (* base5 has no parent *)
  endproc


  process UserInput [user] : noexit :=
      user !base1 !doregister !base3;
      user !base2 !doregister !base3;
      user !base4 !doregister !base5;
      user !base1 !doforward !reqregister(base5);
      user !base1 !doforward !reqachieve(assert(white) + <>);
      stop
      |||
      AllUserReply [user]
  endproc


  library CO4_PROCESSES endlib

endspec